NCXchange: das neutrale NC-Code-Zwischenformat on CNC-Master

Definition: Grammatik der NCX-Sprache

Mon, 01 Jan 0001 00:00:00 +0000

Die NCX-Sprache ist als formale Grammatik in Backus-Naur-Form (BNF) definiert. Ein NC-Programm besteht danach aus Blöcken (Zeilen), die sich aus Zellen der Form [KEYWORD:ADDRESS=VALUE] zusammensetzen.

Grammatik

<program> ::= ( <block> <new-line> )+
<new-line> ::= "\n"
<block> ::= <cell>+
<cell> ::= "[" <content> "]"
<content> ::= <function> "=" <target>
<function> ::= <text> | <text> ":" <address>
<address> ::= <text>
<target> ::= <value> | <value> "," <target>
<value> ::= <text> | <decimal> | <integer>
<decimal> ::= <integer> "." <digits>
<integer> ::= <digits> | "-" <digits>
<digits> ::= <digit>+
<digit> ::= "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
<text> ::= <character>+
<character> ::= "A" ... "Z" | <digit> | "_" | "+"

Die Produktionen im Einzelnen

<program>: Ein Programm besteht aus einem oder mehreren Blöcken, die jeweils mit einem Zeilenumbruch abgeschlossen werden.
<block>: Ein Block ist eine Folge von einer oder mehreren Zellen und entspricht einer Programmzeile.
<cell>: Die Zelle ist die Grundeinheit eines Programms. Jede Zelle besteht aus einem Inhalt, der in eckige Klammern […] eingeschlossen ist.
<content>: Der Inhalt einer Zelle setzt sich aus einer Funktion und einem Ziel zusammen, getrennt durch ein Gleichheitszeichen =.
<function>: Die Funktion gibt an, welche Aktion die Zelle ausführt. Sie besteht entweder aus einem Text oder aus einem Text, gefolgt von einem Doppelpunkt : und einer Adresse.
<address>: Die Adresse ist optional und wird nur verwendet, wenn die Funktion sie benötigt. Sie besteht aus Text.
<target>: Das Ziel gibt an, worauf die Funktion angewendet wird: ein einzelner Wert oder eine durch Kommas getrennte Liste von Werten (z. B. INTERPO=ARC,CCW).
<value>: Ein Wert kann Text, eine Dezimalzahl oder eine Ganzzahl sein.
<decimal>: Eine Dezimalzahl besteht aus einem Ganzzahlteil und einem Nachkommateil, getrennt durch einen Punkt . (z. B. -22.543).
<integer>: Eine Ganzzahl ist eine positive oder negative ganze Zahl ohne Dezimalstellen; negative Zahlen beginnen mit einem Minuszeichen -.
<digits>: Eine Folge von einer oder mehreren Ziffern.
<text>: Text ist eine Folge von einem oder mehreren Zeichen.
<character>: Ein einzelnes Zeichen ist ein Grossbuchstabe A–Z, eine Ziffer, der Unterstrich _ oder das Pluszeichen + (z. B. in WORKPLANE=XY+Z). Leerzeichen sind nicht zulässig.

Beispiel

Ein Block, hier ein Kreisbogen im Uhrzeigersinn mit Mittelpunkt, besteht aus mehreren Zellen:

Spezifikation der NCX-Elemente

Mon, 01 Jan 0001 00:00:00 +0000

Jedes Element der NCX-Sprache wird als eine Zelle der Form [KEYWORD:ADDRESS=VALUE] geschrieben: das Schlüsselwort, optional eine Adresse und der Wert. Die folgende Übersicht dokumentiert alle Elemente mit ihren Adressen, Werten und Beispielen; wo vorhanden, ist zusätzlich der entsprechende konventionelle G- oder M-Befehl angegeben. Die zugrunde liegende Grammatik beschreibt die Definition.

Programm

`PROGRAM`: Programm

Definiert die Kopfdaten eines NC-Programms: Name, Masseinheit und einen optionalen Kommentar.

Schlüsselwort	`PROGRAM`
Adresse	`NAME`: Programmname (Text) `UNIT`: Masseinheit des Programms (MM oder INCH) `COMM`: Kommentar zum Programm (Text)
Werte	`MM`: Millimeter (für UNIT) `INCH`: Zoll (für UNIT)
Beispiel	`PROGRAM:NAME=5544`

Bewegung

`INTERPO`: Interpolation

Legt die Interpolationsart der folgenden Bewegung fest: Eilgang, Arbeitsgang oder Kreisbogen im bzw. gegen den Uhrzeigersinn.

Beispiele: Fanuc-G-Code zu NCX

Mon, 01 Jan 0001 00:00:00 +0000

Die folgenden Beispiele zeigen, wie typische Fanuc-G-Code-Sätze in das NCX-Format umgesetzt werden, jeweils mit dem Ausgangssatz und die entsprechenden NCX-Zellen.

Noch nicht spezifiziert

Die mit * markierten Zeilen verwenden die Radiusprogrammierung sowie die erweiterten Zyklusparameter CYCLE_DELAY, CYCLE_SURFACE_ALTITUDE und CYCLE_DEPTH_INCREMENT. Diese sind von der aktuellen Spezifikation noch nicht abgedeckt. Die Sprache befindet sich noch in Entwicklung.

Kreise und Kreisbögen

Typ	Fanuc	NCX
Kreisbogen mit Mittelpunkt, im Uhrzeigersinn	`G2 X20 Y20 I10 J10`	`[INTERPO=ARC,CW,CENTER][GOTO:X=20][GOTO:Y=20][CENTER:X=10][CENTER:Y=10]`
Kreisbogen mit Mittelpunkt, gegen den Uhrzeigersinn	`G3 X20 Y20 I10 J10`	`[INTERPO=ARC,CCW,CENTER][GOTO:X=20][GOTO:Y=20][CENTER:X=10][CENTER:Y=10]`
Kreisbogen mit Radius, im Uhrzeigersinn *	`G2 X20 Y20 R10`	`[INTERPO=ARC,CW][GOTO:X=20][GOTO:Y=20][RADIUS=10]`
Kreisbogen mit Radius, gegen den Uhrzeigersinn *	`G3 X20 Y20 R10`	`[INTERPO=ARC,CCW][GOTO:X=20][GOTO:Y=20][RADIUS=10]`

Bearbeitungszyklen

Typ	Fanuc	NCX
Bohren	`G81 Z-21.732 F565`	`[CYCLE=DRILL][GOTO:Z=-21.732][FEEDRATE=565]`
Bohren mit Verweilzeit *	`G82 Z-21.732 P0.5 F565`	`[CYCLE=DRILL,DELAY][GOTO:Z=-21.732][CYCLE_DELAY=0.5][FEEDRATE=565]`
Tieflochbohren *	`G83 Z-21.732 R5. Q1.2`	`[CYCLE=DRILL,DEEP_HOLE][GOTO:Z=-21.732][CYCLE_SURFACE_ALTITUDE=5][CYCLE_DEPTH_INCREMENT=1.2]`
Gewindebohren	`G84 Z-20. F750`	`[CYCLE=TAP][GOTO:Z=-20][FEEDRATE=750]`
Reiben	`G85 Z-20. F420`	`[CYCLE=REAM][GOTO:Z=-20][FEEDRATE=420]`
Zyklus beenden	`G80`	`[CYCLE=STOP]`

Längen- und Radiuskompensation

Typ	Fanuc	NCX
Längenkompensation	`G43 Z5. H1`	`[GOTO:Z=5][OFFSET:LEN=1]`
Radiuskompensation links	`G41 Y2. D1`	`[COMPENSATION=LEFT][GOTO:Y=2][OFFSET:DIAM=1]`

Was die einzelnen NCX-Schlüsselwörter bedeuten, dokumentiert die Spezifikation.

NCXchange: das neutrale NC-Code-Zwischenformat on CNC-Master

Definition: Grammatik der NCX-Sprache

Grammatik

Die Produktionen im Einzelnen

Beispiel

Spezifikation der NCX-Elemente

Programm

PROGRAM: Programm

Bewegung

INTERPO: Interpolation

Beispiele: Fanuc-G-Code zu NCX

Kreise und Kreisbögen

Bearbeitungszyklen

Längen- und Radiuskompensation

`PROGRAM`: Programm

`INTERPO`: Interpolation